// @file build.gradle
// Engineer's decor mod gradle build relay (mc1.13.2)
buildscript {
  repositories {
    maven { url = 'https://files.minecraftforge.net/maven' }
    jcenter()
    mavenCentral()
  }
  dependencies {
    classpath group: 'net.minecraftforge.gradle', name: 'ForgeGradle', version: '3.+', changing: true
  }
}
apply plugin: 'net.minecraftforge.gradle'
apply plugin: 'eclipse'
apply plugin: 'maven-publish'
sourceCompatibility = targetCompatibility = compileJava.sourceCompatibility = compileJava.targetCompatibility = '1.8'
//-----------------------------------------------------------------------------
version = "${version_engineersdecor}"
group = "wile.engineersdecor"
archivesBaseName = "engineersdecor-${version_minecraft}"

def signing = { ->
  def sp = new Properties()
  if(file("signing.properties").exists()) file("signing.properties").withInputStream { sp.load(it) }
  return sp
}()

def git_version = { ->
  def stdout = new ByteArrayOutputStream()
  exec {
    commandLine 'git', 'log', '-1', '--format=%h'
    standardOutput = stdout
  }
  return stdout.toString().trim()
}()

repositories {
  maven { name = "Progwml6 maven"; url = "https://dvs1.progwml6.com/files/maven/" } // JEI files
  maven { name = "ModMaven"; url = "modmaven.k-4u.nl" } // JEI files, fallback
}

minecraft {
  mappings channel: 'snapshot', version: "${version_fml_mappings}"
  // accessTransformer = file('build/resources/main/META-INF/accesstransformer.cfg')
  runs {
    client {
      workingDirectory project.file('run')
      property 'forge.logging.markers', 'SCAN,REGISTRIES,REGISTRYDUMP'
      property 'forge.logging.console.level', 'debug'
      mods {
        engineersdecor {
          source sourceSets.main
        }
      }
    }
    server {
      workingDirectory project.file('run')
      property 'forge.logging.markers', 'SCAN,REGISTRIES,REGISTRYDUMP'
      property 'forge.logging.console.level', 'debug'
      mods {
        engineersdecor {
          source sourceSets.main
        }
      }
    }
    data {
      workingDirectory project.file('run')
      property 'forge.logging.markers', 'SCAN,REGISTRIES,REGISTRYDUMP'
      property 'forge.logging.console.level', 'debug'
      args '--mod', 'engineersdecor', '--all', '--output', file('src/generated/resources/')
      mods {
        engineersdecor {
          source sourceSets.main
        }
      }
    }
  }
}

dependencies {
  minecraft "net.minecraftforge:forge:${version_forge_minecraft}"
  compileOnly fg.deobf("mezz.jei:jei-${version_jei}:api")
  runtimeOnly fg.deobf("mezz.jei:jei-${version_jei}")
}

jar {
  manifest {
    attributes([
      "Specification-Title": "engineersdecor",
      "Specification-Vendor": "wilechaote",
      "Specification-Version": "1", // We are version 1 of ourselves
      "Implementation-Title": project.name,
      "Implementation-Version": "${version_engineersdecor}",
      "Implementation-Vendor" :"wilechaote",
      "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
    ])
  }
}

def reobfFile = file("$buildDir/reobfJar/output.jar")
def reobfArtifact = artifacts.add('default', reobfFile) { type 'jar'; builtBy 'reobfJar'; }

publishing {
  publications { mavenJava(MavenPublication) { artifact reobfArtifact } }
  repositories { maven { url "file:///${project.projectDir}/mcmodsrepo" } }
}