plugins {
    id 'java'
    id 'maven-publish'
}

repositories {
    flatDir {
        dirs "libs"
    }
    maven {
        url "https://libraries.minecraft.net/"
    }
    maven {
        url "https://maven.zontreck.com/repository/internal"
    }
    maven {
        url "https://maven.zontreck.com/repository/zontreck"
    }
    mavenCentral()
}

group = 'dev.zontreck'
archivesBaseName = 'launchwrapper'
version = '1.0-SNAPSHOT'
sourceCompatibility = 1.5
targetCompatibility = 1.5

dependencies {
    implementation 'dev.zontreck:RetroDebugInjector:1.0'
    implementation 'org.ow2.asm:asm:9.3'
    implementation 'org.ow2.asm:asm-tree:9.3'
    implementation 'org.json:json:20230311'
    // I'll bring discord RPC support later, when I have an environment to compile natives

    testImplementation 'junit:junit:4.12'
    testImplementation 'org.junit.jupiter:junit-jupiter-engine:5.0.0'
}

test {
    useJUnitPlatform()
}

task sourcesJar(type: Jar) {
    archiveClassifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives jar
    archives sourcesJar
}

def MAVEN_PASSWORD_PROPERTY = "AriasCreationsMavenPassword"
publishing {
    publications {
        mavenJava(MavenPublication) {
            artifact jar
            artifact sourcesJar
        }
    }
    repositories {
        maven {
            url = "https://maven.zontreck.com/repository/zontreck"
            name = "ariascreations"
            if (project.findProperty(MAVEN_PASSWORD_PROPERTY) != null) {
                credentials {
                    username = "admin"
                    password = project.findProperty(MAVEN_PASSWORD_PROPERTY)
                }
            }
        }
    }
}