plugins {
    // Apply the java-library plugin for API and implementation separation.
    id 'java-library'
    id 'idea'
    id 'eclipse'
    id 'maven-publish'
}

group = "dev.zontreck"
archivesBaseName = "LibAC"

def ENV = System.getenv()

java {

    withSourcesJar()
    withJavadocJar()
}

def determinePatchVersion = {
    // get the name of the last tag
    def tagInfo = new ByteArrayOutputStream()
    exec {
        commandLine 'git', 'describe', '--tags'
        standardOutput = tagInfo
    }
    tagInfo = tagInfo.toString()

    if (!tagInfo.contains('-')) {
        return 0
    }
    return tagInfo.split("-")[1]
}

version = determinePatchVersion()
version = "${apiVer}.${version}"

repositories {
    // Use Maven Central for resolving dependencies.
    // mavenCentral()
}

dependencies {

}

def MAVEN_PASSWORD = "AriasCreationsMavenPassword"
def MAVEN_USER = "AriasCreationsMavenUser"

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifact jar
            artifact sourcesJar
            artifact javadocJar
        }
    }

    repositories {
        maven {
            url = "https://git.zontreck.com/api/packages/AriasCreations/maven"
            name = "ariascreations"

            credentials {
                username = project.findProperty(MAVEN_USER)
                password = project.findProperty(MAVEN_PASSWORD)
            }
        }
    }
}

test {
    useJUnitPlatform()
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}